User defined data types

Type definition

   TYPE TypeName [EXTENDS BaseTypeName]
   END TYPE

   TYPE Tphone
      INTEGER Id
      DIM Name$[30],Phone$[20]
   END TYPE

   TYPE Tphone_ex EXTENDS Tphone
      DIM Comment$[40]
   END TYPE

In addition to a type definition in the program, data types can be defined from the database schema.

   IN DATA SET data_set DEFINE TYPE type_name

The example below defines the data type Tcustomer from the data set CUSTOMER.

   DBOPEN(Db$,"",1,S(*))
   ...
   IN DATA SET "CUSTOMER" DEFINE TYPE Tcustomer

• If a type is defined globally (in the main program), it is available to all subprograms and functions. It is deleted, when another program is LOADed.
• If defined in a SUB/FN program segment, a type definition is only known inside the subprogram. In addition, it can be passed to other functions and subprograms as an argument. The type definition is deleted when the segment returns.

DIM and COM statements:

   COM Instance_name:Type_name
   COM Instance_name AS Type_name
   DIM Instance_name:Type_name
   DIM Instance_name AS Type_name

   NEW Instance_name:Type_name
   NEW Instance_name AS Type_name

The example below defines the variables Phone1 and Phone2. They are of type Tphone.

   DIM Phone1:Tphone
   NEW Phone2 AS Tphone

In addition, the NEW STRUCT statement can be used to create a new, identical copy of the referenced object.

   NEW STRUCT Instance_name=Instance_Name

   DIM Entry:Tphone
   Entry.Name$="Joe Sample"
   Entry.Phone$="(202) 243 1440"
   NEW STRUCT Clone=Entry

   Phone1.Comment$="*Fancy Comment*"
   PRINT Phone1.Comment$

   PRINT STRUCT Entry

The STRUCT statement can also be used to copy the value of an object:

   STRUCT A=B

• Both objects must have the same data type. In this case, all member variables are copied.
• Both objects must have a common base type. In this case, only the common member variables are copied.

Passing a struct to a subprogram or function

   CALL Sub(STRUCT A)
   ...
   SUB Sub(A {AS|:} TypeName)
   SUB Sub(STRUCT A)

For example:

   TYPE Type
      INTEGER I
   END TYPE
!
   DIM Inst:Type
   Inst.I=0
   CALL Sub(Inst)
   PRINT Inst.I
   CALL Sub((Inst))
   PRINT Inst.I
   STOP
!
   SUB Sub(STRUCT A)
      A.I=A.I+1
   SUBEND

• When a type is specified and it is defined globally, the passed variable must either be of the same type or it must have a common base type.
• Then the type specified is not defined globally, it is defined with the given name from the parent environment.

! Define type Tsample
   TYPE Tsample
      INTEGER I
      DIM X$[20]
   END TYPE

! DIM variable A with type Tsample
   DIM A AS Tsample

! Pass A to SUB
   CALL Sub1(STRUCT A)
   CALL Sub2(STRUCT A)
   STOP

! Sub1 requires a type Tsample (or any derived type)
   SUB Sub1(A AS Tsample)
      PRINT A.I;A.X$
   SUBEND

! Sub2 does accept an anoymous variable
   SUB Sub2(STRUCT A)
      PRINT A.I;A.X$
   SUBEND

The STRUCT keyword

The following statements can be used with STRUCT:

• PRINT
• READ
• PRINT #, READ #
• IN DATA SET USE, IN DATA SET LIST
• PACKFMT
• XPACK, XUNPACK

Runtime type identification

   X$=TYPEOF$(instance_name)

The IS A operator can be used to categorize an instance.

   IF instance_name IS A type_name THEN ...

For example:

   TYPE Tbase
      INTEGER A
   END TYPE
   TYPE Tderived EXTENDS Tbase
      INTEGER Q
   END TYPE
!
   DIM Derived:Tderived,Base:Tbase
   DISP "Base is of type ";TYPEOF$(Base)
   DISP "Inst is of type ";TYPEOF$(Derived)
   DISP "Base    is a Tbase    =";Base IS A Tbase
   DISP "Base    is a Tderived =";Base IS A Tderived
   DISP "Derived is a Tbase    =";Derived IS A Tbase
   DISP "Derived is a Tderived =";Derived IS A Tderived
   STOP

Data base integration

   DBOPEN(Db$,"",1,S(*))
   ...
   IN DATA SET "CUSTOMER" DEFINE TYPE Tcust
   NEW Cust:Tcust
   IN DATA SET "CUSTOMER" USE STRUCT Cust
   ...
   DBGET(Db$,"CUSTOMER",7,S(*),"@",Buf$,Key$)
   ...

   TYPE Tcust
      DIM No$[6]
      DIM Name$[30]
      ...
   END TYPE
   DIM Cust:Tcust
!
   DBOPEN(Db$,"",1,S(*))
   ...
   IN DATA SET "CUSTOMER" USE STRUCT Cust
   ...
   DBGET(Db$,"CUSTOMER",7,S(*),"@",Buf$,Key$)
   ...

XPACK and XUNPACK

Error Messages

Example program

! common block
TYPE Tglobal
  INTEGER Iv
  DIM Xv$[18]
  INTEGER A(1:2)
END TYPE
!
COM Global:Tglobal
READ STRUCT Global
DATA 123,"COMMON",1,2
!
PRINT "Global.Iv=";Global.Iv
PRINT "Global.Xv$=";Global.Xv$
PRINT "Global.A(*)=";Global.A(1);Global.A(2)
CALL Sub
STOP
!
SUB Sub
   COM Global:Tglobal
   PRINT "Global.Iv=";Global.Iv
   PRINT "Global.Xv$=";Global.Xv$
   PRINT "Global.A(*)=";Global.A(1);Global.A(2)
SUBEND